If I remember, the "ANHT" hac was more closely related to the LT5 code at the time. It almost seemed like the various operating code sections were pulled from a menu and inserted into whatever calibration they needed to create at the time. All the LT5 calibrations are similar, but you can tell over time where they added some tweaks and minor functionality here and there. The BMCB version strikes me as the most advanced. Makes sense since it was among the final releases.
Here's a snippet of the BFXB code, which determines the target air-fuel ratio in open loop, and then applies the richest of the calculated ratios to determine the final ratio.
Code:
******************************************************
** OPEN LOOP/CLOSED LOOP FUEL/AIR RATIO CALCULATION
******************************************************
OLCLAIRF CLRA
LDAB FATI TIMEOUT A/F RATIO
ADDB KFABIAS OPEN LOOP F/A BIAS USED TO SET UP LEAN LIMIT
ADCA #0
ADDB FATC COOL TEMP F/A RATIO OFFSET
ADCA #0
PSHB
PSHA
BRSET MWFA1;BIT7,FAADDVAP 1=CLOSED LOOP MODE (BOTH SENSORS CL)
******************************************************
*** ADD MAP BASED TERM (VAPORIZATION FACTOR) IF IN OPEN LOOP
******************************************************
LDAA NMAPLD NORMALIZED MAP VALUE
LDX #F50H OPEN LOOP FUEL/AIR % CHANGE V. MAP
JSR P4LKUPQ 2D TABLE LOOKUP, NO OFFSET, SPACED 16
STAA FAVAPF FUEL/AIR VAPORIZATION FACTOR
FAADDVAP PULA
PULB
ADDB FAVAPF FUEL/AIR VAPORIZATION FACTOR
ADCA #0
******************************************************
*** APPLY ALL FUEL/AIR MODIFICATION TERMS TO STOCHIOMETRIC
******************************************************
MULFAST LDX KFASTCN STOCHIOMETRIC A/F RATIO
JSR P4M1616C 16X16 MULTIPLY RETURN W/ MIDDLE 2 BYTES
STD FAVALNPE NON-PWR ENRICH F/A VALUE
******************************************************
** PE FUEL-AIR RATIO CALCULATION
******************************************************
BRCLR MWFA;BIT5,PEAIRFLX 1=POWER ENRICHMENT ACTIVE
LDX #F68E POWER ENRICH FUEL/AIR % CHG V. RPM
LDAA NTRPMX RPM/25
CMPA #160
BHI PEAF001
SUBA #16
BCC PEAF002
CLRA
BRA PEAF002
PEAF001 LDAA NTRPMZ RPM/31.25
ADDA #16
BCC *+4
LDAA #255
PEAF002 JSR P4LKUPQ 2D TABLE LOOKUP, NO OFFSET, SPACED 16
TAB
LDX #128
ABX
LDAB LKUPF67 F67 LOOKUP IN 100 MSEC COOLVAR
ABX
LDD KFASTCN STOCHIOMETRIC A/F RATIO
JSR P4M1616C 16X16 MULTIPLY RETURN W/ MIDDLE 2 BYTES
STD FAVALPE PWR ENRICH F/A VALUE
PEAIRFLX EQU *
******************************************************
* RICHEST FUEL/AIR RATIO (P.E. OR NON-P.E.) DETERMINATION LOGIC
******************************************************
FAVALUPD LDX FAVALPE PWR ENRICH F/A VALUE
CPX FAVALNPE NON-PWR ENRICH F/A VALUE
BHI *+5
LDX FAVALNPE NON-PWR ENRICH F/A VALUE
LCB36 STX FAVAL FINAL TOTAL F/A VALUE